# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

JAVA_PKG_IUSE="examples"

inherit autotools eutils flag-o-matic java-pkg-2 java-ant-2 versionator

MY_PN=rJava
MY_PV=$(replace_version_separator 2 '-' )
MY_P=${MY_PN}_${MY_PV}
S=${WORKDIR}/${MY_PN}

DESCRIPTION="The R-Java interface (also includes JRI)"
HOMEPAGE="http://www.rforge.net/rJava/"
SRC_URI="http://www.rforge.net/${MY_PN}/snapshot/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE=""

COMMON_DEP=">=dev-lang/R-2.5.0"

RDEPEND=">=virtual/jre-1.6
	${COMMON_DEP}"

DEPEND=">=virtual/jdk-1.6
	${COMMON_DEP}"

pkg_setup() {
	java-pkg-2_pkg_setup

	if use x86 ; then
	    jvmarch=i386
	else
	    jvmarch=${ARCH}
	fi
}

src_unpack() {
	unpack ${A}
	cd "${S}"
}

src_compile() {
	setup-jvm-opts
	export R_HOME="/usr/$(get_libdir)/R"
	econf --enable-jri || die "econf failed"
	cd src/
	make -f Makevars || die "make failed"
}

src_install() {
	export R_LIBS_SITE="${R_HOME}/site-library"
	dodir ${R_LIBS_SITE}
	cd ${WORKDIR}
	R CMD INSTALL -l "${D}${R_LIBS_SITE}" ${MY_PN} \
	    || die "install failed"

	cd ${S}
	java-pkg_jarinto /usr/$(get_libdir)/jri
	#java-pkg_sointo /usr/$(get_libdir)/jri
	java-pkg_dojar inst/jri/JRI.jar
	#java-pkg_doso inst/jri/libjri.so

	insinto /usr/$(get_libdir)/jri
	insopts -m0755
	doins inst/jri/libjri.so

	dodoc NEWS
	newdoc jri/README README.jri
	use examples && java-pkg_doexamples jri/examples
}

setup-jvm-opts() {
	# Figure out correct boot classpath
	# stolen from eclipse-sdk ebuild
	local bp="$(java-config --jdk-home)/jre/lib"
	local bootclasspath=$(java-config --runtime)
	if [[ ! -z "`java-config --java-version | grep IBM`" ]] ; then
		# IBM JDK
		JAVA_LIB_DIR="$(java-config --jdk-home)/jre/bin"
	else
		# Sun derived JDKs (Blackdown, Sun)
		JAVA_LIB_DIR="$(java-config --jdk-home)/jre/lib/${jvmarch}"
	fi

	einfo "Using bootclasspath ${bootclasspath}"
	einfo "Using JVM library path ${JAVA_LIB_DIR}"

	if [[ ! -f ${JAVA_LIB_DIR}/libawt.so ]] ; then
		die "Could not find libawt.so native library"
	fi

	export AWT_LIB_PATH=${JAVA_LIB_DIR}
}